Sony EVI D100

David_w

Trying to program a Sony EVI D100, to power the unit on and off. I am not sure if I am reading the RS-232 commands right. anyone let me know if that is right. The QQ would be the command string. The 8X.... is the ON string.


{
send_string dvCam,"'QQ',13"
wait 10 send_string dvCam,"'8x01040002FF',13"
SEND_STRING 0, "'8x01040002FF',13"
}

dthorson

Read the protocol manual more closely you'll probably find that the 8X is the device ID, and all the strings should be sent in HEX not ascii as you have it.

here some sample code that may help you: Notice the stop move command takes place in the RELEASE:{}


PROGRAM_NAME='SONY EVI 100'
(*=====================================================*)
(* Button Event Name: VC_CAM3_BTNS *)
(* Purpose: Controls camera through AMX module *)
(*=====================================================*)
BUTTON_EVENT[VC_CAM3_BTNS]
{
PUSH:
{
LOCAL_VAR INTEGER CAM3_CURRENT_PRESET
LOCAL_VAR INTEGER CAM3_BUTTON
CAM3_BUTTON = BUTTON.INPUT.CHANNEL
IF (CAM3_BUTTON > 40)
{
CAM3_CURRENT_PRESET = CAM3_BUTTON - 40
}
SWITCH(CAM3_BUTTON)
{
CASE 31: (*TILT UP*)
{
//SEND_STRING dvSONYCAM,SONYCAM_UP
SEND_STRING dvSONYCAM,"$81,$01,$06,$01,$07,$07,$03,$01,$FF"
}
CASE 32: (*TILT DOWN*)
{
//SEND_STRING dvSONYCAM,SONYCAM_DOWN
SEND_STRING dvSONYCAM,"$81,$01,$06,$01,$07,$07,$03,$02,$FF"
}
CASE 33: (*PAN RIGHT*)
{
//SEND_STRING dvSONYCAM,SONYCAM_RIGHT
SEND_STRING dvSONYCAM,"$81,$01,$06,$01,$10,$10,$02,$03,$FF"
}
CASE 34: (*PAN LEFT*)
{
//SEND_STRING dvSONYCAM,SONYCAM_LEFT
SEND_STRING dvSONYCAM,"$81,$01,$06,$01,$10,$10,$01,$03,$FF"
}
CASE 35: (*FOCUS IN*)
{
//SEND_STRING dvSONYCAM,SONYCAM_NEAR
SEND_STRING dvSONYCAM,"$81,$01,$04,$08,$03,$FF"
}
CASE 36: (*FOCUS OUT*)
{
//SEND_STRING dvSONYCAM,SONYCAM_FAR
SEND_STRING dvSONYCAM,"$81,$01,$04,$08,$02,$FF"
}
CASE 37: (*ZOOM IN*)
{
//SEND_STRING dvSONYCAM,SONYCAM_TELE
SEND_STRING dvSONYCAM,"$81,$01,$04,$07,$02,$FF"
}
CASE 38: (*ZOOM OUT*)
{
//SEND_STRING dvSONYCAM,SONYCAM_WIDE
SEND_STRING dvSONYCAM,"$81,$01,$04,$07,$03,$FF"
}
CASE 40: (*SAVE PRESET*)
{
SEND_STRING dvSONYCAM,"$81,$01,$04,$3F,$01,(CAM3_CURRENT_PRESET-1),$FF"
SEND_STRING 0,"$81,$01,$04,$3F,$01,CAM3_CURRENT_PRESET,$FF"
}
}
IF((CAM3_BUTTON >= 41) AND (CAM3_BUTTON <= 44)) (*RECALL PRESET*)
{
SEND_STRING dvSONYCAM,"$81,$01,$04,$3F,$02,(CAM3_CURRENT_PRESET-1),$FF"
SEND_STRING 0,"$81,$01,$04,$3F,$02,CAM3_CURRENT_PRESET,$FF" SEND_STRING 0,"10,13"
}
}
RELEASE:
{
LOCAL_VAR INTEGER BUTTON_RELEASE
BUTTON_RELEASE = BUTTON.INPUT.CHANNEL
SELECT
{
ACTIVE((BUTTON_RELEASE = 35)OR(BUTTON_RELEASE = 36)):
{
SEND_STRING dvSONYCAM, "$81,$01,$04,$08,$00,$FF"
}
ACTIVE((BUTTON_RELEASE = 37)OR(BUTTON_RELEASE = 38)):
{
SEND_STRING dvSONYCAM, "$81,$01,$04,$07,$00,$FF"
}
ACTIVE((BUTTON_RELEASE >= 31)AND(BUTTON_RELEASE <= 34)):
{
SEND_STRING dvSONYCAM, "$81,$01,$06,$01,$18,$18,$03,$03,$FF"
}
}
}
}

Thomas Hayes

I used these for the Elmo camera which I believe is the same as the Sony one,

VOLATILE CAM_ON[] ={$81,$01,$04,$00,$02,$FF}
VOLATILE CAM_OFF[] ={$81,$01,$04,$00,$03,$FF}

dthorson

Here's the strings ON/OFF

Cam_on = "$81,$01,$04,$00,$02,$ff"
Cam_off = "$81,$01,$04,$00,$03,$ff"
Cam_zoom_tele = "$81,$01,$04,$07,$02,$ff"
Cam_zoom_wide = "$81,$01,$04,$07,$03,$ff"
Cam_zoom_stop = "$81,$01,$04,$07,$00,$ff"
Cam_focus_far = "$81,$01,$04,$08,$03,$ff"
Cam_focus_near = "$81,$01,$04,$08,$02,$ff"
Cam_focus_stop = "$81,$01,$04,$08,$00,$ff"
Cam_up = "$81,$01,$06,$01,$07,$07,$03,$01,$ff"
Cam_down = "$81,$01,$06,$01,$07,$07,$03,$02,$ff"
Cam_left = "$81,$01,$06,$01,$07,$07,$01,$03,$ff"
Cam_right = "$81,$01,$06,$01,$07,$07,$02,$03,$ff"
Cam_drive_stop = "$81,$01,$06,$01,$03,$03,$03,$03,$ff"
Cam_home = "$81,$01,$06,$04,$ff"

David_w

Thank you

Hey Thank you very much as soon as I saw that I was able to fix some mistakes.