Best Of

Put the ONERROR event and the GET_IP_ERROR function in your code so you can see the error number in diagnostics and then determine what type of IP error it is. My guess is your sending an IP_CLIENT_CLOSE when the port is no longer open which is harmless except for the error message it generates. A lot of connections close automatically so sending the close isn't always necassary. So if your not sure just put a condition if front of the close so that it is only sent if you are still online.

like:

 if (nIP_DeviceOnline)//put where ever it belongs
	  {
	  IP_CLIENT_CLOSE (dvIP_Device.port)
	  }

Put this in your ONERROR data event:

DATA_EVENT   [dvIP_Device]
     {
     ONLINE:
	  {
	  nIP_DeviceOnline = 1 ;
	  }
	  OFFLINE:
	  {
	  nIP_DeviceOnline = 0 ;
	  }
	 ONERROR:
	  {
	  if (data.number <> 0) // data.number = 0 -> No error
	       {
	       SEND_STRING 0,"'Device ',DEV_TO_STRING(DATA.Device),':',GET_IP_ERROR(DATA.Number),' line-<',ITOA(__LINE__),'>',13,10"
		   }
	  }
     STRING:
	  {
          // nothing
	  }
     }
 

Put this function some where:

 DEFINE_FUNCTION CHAR[100] GET_IP_ERROR (LONG lERR)
     {
     SWITCH (lERR)
	  {
	  CASE 0:
	       RETURN "";
	  CASE 2:
	       RETURN "'IP ERROR (',ITOA(lERR),'): General Failure (IP_CLIENT_OPEN/IP_SERVER_OPEN)'";
	  CASE 4:
	       RETURN "'IP ERROR (',ITOA(lERR),'): unknown host (IP_CLIENT_OPEN)'";
	  CASE 6:
	       RETURN "'IP ERROR (',ITOA(lERR),'): connection refused (IP_CLIENT_OPEN)'";
	  CASE 7:
	       RETURN "'IP ERROR (',ITOA(lERR),'): connection timed out (IP_CLIENT_OPEN)'";
	  CASE 8:
	       RETURN "'IP ERROR (',ITOA(lERR),'): unknown connection error (IP_CLIENT_OPEN)'";
	  CASE 9: // not used
	       {
	       RETURN "'IP ERROR (',ITOA(lERR),'): Already closed (IP_CLIENT_CLOSE/IP_SERVER_CLOSE)'";  
	       }
	  CASE 10:
	       RETURN "'IP ERROR (',ITOA(lERR),'): Binding error (IP_SERVER_OPEN)'";
	  CASE 11:
	       RETURN "'IP ERROR (',ITOA(lERR),'): Listening error (IP_SERVER_OPEN)'";  
	  CASE 14: // not used
	       {
	       RETURN "'IP ERROR (',ITOA(lERR),'): local port already used (IP_CLIENT_OPEN/IP_SERVER_OPEN)'";
	       }
	  CASE 15:
	       RETURN "'IP ERROR (',ITOA(lERR),'): UDP socket already listening (IP_SERVER_OPEN)'";
	  CASE 16:
	       RETURN "'IP ERROR (',ITOA(lERR),'): too many open sockets (IP_CLIENT_OPEN/IP_SERVER_OPEN)'";
	  CASE 17:
	       RETURN "'IP ERROR (',ITOA(lERR),'): Local port not open'";
	  DEFAULT:
	       RETURN "'IP ERROR (',ITOA(lERR),'): Unknown'";
	  }
     }
 

Here's the other function:

DEFINE_FUNCTION CHAR[17] DEV_TO_STRING (DEV dvDEV)
     {
     RETURN "FORMAT('%d',dvDEV.NUMBER),':',FORMAT('%d',dvDEV.PORT),':',FORMAT('%d',dvDEV.SYSTEM)"
     }

I don't know who originated these two functions but they are essential when doing IP communications.